UWSC入門:Seesaaブログ自動投稿スクリプト

意外とめんどくさいブログ記事の投稿ですが(私はタグの登録がめんどくさいですね。)、自動投稿のスクリプトでいくらか時間短縮ができます。(2〜3分ぐらいかな?)
今回はSeesaaブログでブログ記事を自動投稿するスクリプトを書いてみたいと思います。
ブログ投稿で今回入力する項目は下記とします。


・記事カテゴリ
・記事タイトル
・記事のタグ
・内容
・追記
・キーワード


ブログ記事を書くテンプレート作成


いくつか項目があるので最初にブログ記事を書くテンプレートを作っておくと便利です。
下記が今回使用するテンプレートです。

$記事カテゴリ$
記事カテゴリ
$記事カテゴリ$
$記事タイトル$
記事タイトル
$記事タイトル$
$記事のタグ$
記事のタグ
$記事のタグ$
$内容$
内容
$内容$
$追記$
追記
$追記$

「$」で囲っていないそれぞれの項目にそれぞれの内容を書いていきます。例えば「$記事カテゴリ$(改行)記事カテゴリー(改行)$記事カテゴリ$」となっている「記事カテゴリー」の部分に書きます。
テンプレートにキーワードがないのは、私の場合「タグ」をキーワードにしてしまうので、タグの内容を投稿時にキーワードに変換するからです。キーワードを別に登録する方はテンプレートにキーワード入力欄を作ってください。

テンプレートの保存場所はCドライブ直下としています。
Cドライブ直下に「SeesaaBlog」というフォルダを作成し、「SeesaaBlog」フォルダの中に「TMP」フォルダを作成し、「TMP」フォルダ「tmp.html」というファイルを作成して下さい。
「tmp.html」ファイルに上記のテンプレートを貼り付けて使用して下さい。( C:\SeesaaBlog\TMP\tmp.html )
※今回 html ファイルにしているのは、私は編集する際に Dream Weaver を使用しているので html ファイルの方が何かと便利なので メモ帳などを使う方は拡張子を「txt」とするとよいです。その場合、以下に出てくるソースコードで使うファイル名は「tmp.txt」としてください。
また、今回作成するテンプレートも記事を書くたびに更新するのはめんどくさいので、記事投稿後リセットするので「TMP」フォルダの中に「tmp_BU.html」というファイルを作成し「tmp.html」と同じようにテンプレートをコピペしておいてください。( C:\SeesaaBlog\TMP\tmp_BU.html )

バックアップファイルの作成


今回、投稿した記事のバックアップと投稿時にログ(投稿履歴のようなもの)を作成したいと思います。
上記で作成した「SeesaaBlog」フォルダの中に「article」フォルダと「DB」フォルダを作成してください。「DB」フォルダの中に「Log.html」ファイルを作成します。
「Log.html」ファイルの中身に下記を貼り付けておいてください。
( C:\SeesaaBlog\article C:\SeesaaBlog\DB\Log.html )

ブログID,記事ID,記事タイトル,記事カテゴリ,投稿日時,キーワード

これで拡張子を「html」から「csv」に変更すればcsvファイルとして見ることができます。

ブログID取得


Seesaaブログで複数のブログを運営されている方やこれからいくつかブログを運営していこうという方は投稿するブログのブログIDを取得しておくことをお勧めします。
今回はブログIDを取得しておき、ブログIDを含めたURLページを開きます。
マイ・ブログからブログタイトルにマウスを合わせるとステータスバーにブログIDを含めたURLが表示されます。

UWSC入門:Seesaaブログ自動投稿スクリプト

「?blog_id=ブログID」のブログIDの文字列が投稿するブログIDになるので下記のスクリプトの1行目「CONST BlogID = "0000000"」の「0000000」のところにブログIDを貼り付けてスクリプトを使用してください。
FireFoxであれば右クリック「リンクのURLをコピー」でリンクをコピーできるます。

Seesaaブログ自動投稿スクリプト


これでスクリプトを書く準備が終わりました。
テンプレート( tmp.html )に入力項目を記載し下記スクリプトを実行すればSeesaaブログの自動投稿からバックアップ作成、テンプレートリセットまでが実行されます。


CONST BlogID = "0000000"
CONST BlogUrl = "http://blog.seesaa.jp/pages/my/blog/home/?blog_id=" + BlogID

IE = CREATEOLEOBJ("InternetExplorer.Application")
IE.visible = True
IE.navigate( BlogUrl )

REPEAT
UNTIL !IE.busy AND IE.readystate=4

FID_TMP = FOPEN( "C:\SeesaaBlog\TMP\tmp.html", F_READ )
TMP = FGET( FID_TMP, F_ALLTEXT )
FCLOSE( FID_TMP )

Kiji_Category = BETWEENSTR( TMP, "$記事カテゴリ$<#CR>", "<#CR>$記事カテゴリ$" )
Kiji_title = BETWEENSTR( TMP, "$記事タイトル$<#CR>", "<#CR>$記事タイトル$" )
Tag = BETWEENSTR( TMP, "$記事のタグ$<#CR>", "<#CR>$記事のタグ$" )
Keyword = REPLACE( Tag, "<#CR>", "," )
EntryBody = BETWEENSTR( TMP, "$内容$<#CR>", "<#CR>$内容$" )
EntryBodyMore = BETWEENSTR( TMP, "$追記$<#CR>", "<#CR>$追記$" )

IESETDATA( IE, Kiji_Category, "category__name" ) //記事カテゴリ入力
IESETDATA( IE, 1, "", "カテゴリの追加" ) //記事カテゴリ追加
IESETDATA( IE, Kiji_title, "article__subject" ) //記事タイトル入力
IESETDATA( IE, EntryBody, "article__body" ) //内容入力
IESETDATA( IE, EntryBodyMore, "article__body_more" ) //追記入力
IESETDATA( IE, Keyword, "article__topics" ) //キーワード入力

WHILE LENGTH( Tag ) > 1
Tag_To = TOKEN( "<#CR>", Tag )
IESetData(IE, Tag_To, "__tag") //タグ入力
IESetData(IE, 1, "", "タグの追加") //タグ追加
WEND

IESETDATA( IE, 1, "", "保存する" ) //投稿

REPEAT
UNTIL !IE.busy AND IE.readystate=4
REPEAT
UNTIL !IE.busy AND IE.readystate=3
REPEAT
UNTIL !IE.busy AND IE.readystate=4

GET_ID = IEGETDATA( IE, "id" ) //ブログID取得
GET_Time = IEGETDATA( IE, "article__createstamp" ) //記事の投稿日時

//ログ作成
LOG = BlogID + "," + GET_ID + "," + Kiji_title + "," + Kiji_Category + "," + GET_Time + "," + REPLACE( Keyword, ",", "#" )
FID_LOG = FOPEN( "C:\SeesaaBlog\DB\Log.html", F_READ OR F_WRITE )
FPUT( FID_LOG, LOG, 2, F_INSERT )
FCLOSE( FID_LOG )

//バックアップファイル作成
FID_BackUp = FOPEN( "C:\SeesaaBlog\article\" + GET_ID + ".html" , F_WRITE )
FPUT( FID_BackUp, TMP )
FCLOSE( FID_BackUp )

//テンプレートリセット
FID_TMP = FOPEN( "C:\SeesaaBlog\TMP\tmp.html", F_WRITE )
FID_TMPBackUp = FOPEN( "C:\SeesaaBlog\TMP\tmp_BU.html", F_READ )
GET_TMPBackUp = FGET( FID_TMPBackUp, F_ALLTEXT )
FPUT( FID_TMP, GET_TMPBackUp )
FCLOSE( FID_TMP )
FCLOSE( FID_TMPBackUp )

IE.QUIT
EXITEXIT


次回、今回書いたスクリプト「Seesaaブログ自動投稿スクリプト」の解説をします。

posted by 寺澤キングダム at 20:31 | Comment(1) | TrackBack(0) | UWSC | このブログの読者になる | 更新情報をチェックする
この記事へのコメント
こちらのブログはとても勉強になります。

この記事も参考にして自分なりに書いてみたのですが、1つつまづいています。

「キーワード入力」のところです。
IESETDATA で同じように書いたのですが、うまく入力することができないのです。

+ボタンをクリックして、詳細設定を一度開いてから、もう一度UWSCを再生すると、きちんと入力できるのですが・・・

詳細設定の+ボタンをクリックする書き方がわかりません。

また、IESETDATA だけで記入できるならそれもいいのですが。

お分かりになるようでしたら、是非教えてください。よろしくお願いします。

Posted by まろやか at 2012年07月19日 22:30
コメントを書く
お名前:

メールアドレス:

ホームページアドレス:

コメント: [必須入力]

認証コード: [必須入力]


※画像の中の文字を半角で入力してください。
※ブログオーナーが承認したコメントのみ表示されます。

この記事へのトラックバック
×

この広告は1年以上新しい記事の投稿がないブログに表示されております。